b0in.xyz

packer {
  required_plugins {
    qemu = {
      version = "~> 1"
      source  = "github.com/hashicorp/qemu"
    }
  }
}

source "qemu" "rocky9" {
  # You'll need the iso_url and checksum
  iso_url          = "..."
  iso_checksum     = "sha256:..."
  output_directory = "out"
  shutdown_command = "echo 'changemerocky' | sudo -S shutdown -P now"

  # this size is awfully big but the 'qcow2' format is "sparse". that means
  # that it won't take up that much space unless
  disk_size        = "100000M"
  format           = "qcow2"

  # without kvm and qemuargs -cpu host i kept getting kernel panics!
  # But you have to have kvm setup
  accelerator      = "kvm"
  qemuargs = [[
    "-cpu", "host"
  ]]
    
  # without expanding the memory, the ramdisk kept filling up
  memory         = "1024"

  # user and pass are created by the kickstart files
  ssh_username   = "rocky"
  ssh_password   = "changemerocky"
  ssh_timeout    = "10m"

  vm_name        = "rocky9-example"
  boot_wait      = "5s"

  # the kickstart file references /dev/vda and it comes from this.
  disk_interface = "virtio"

  # The opearting system on the iso file can reach out to the network.
  http_directory = "kickstart/"
  boot_command = [
    # tab to swap to a mode that lets you type in stuff into the default linux kernel args
    "<tab>", 
    # delete the phrase 'quiet' so we can get more text.
    "<bs><bs><bs><bs><bs>",
    # inst.text puts the installer in text mode as we may not have a monitor.
    #   lots of sources just use 'text' and 'ks' but those do not work 
    #   in newer versions of rocky
    "inst.text",
    # inst.ks is how we get the booted system to find the rest of the installation
    # instructions. we fetch it from the network! [1]
    "inst.ks=http://{{ .HTTPIP }}:{{ .HTTPPort }}/rocky9-kvm-ks.cfg",
    # enter causes us to boot and well, wait does what it says
    "<enter><wait>"
  ]
}